  SUBROUTINE tssub_advdify_q(sal,temp   &

                                      ,c &

                                        )

!&E---------------------------------------------------------------------
!&E                 ***  ROUTINE tssub_advdify_quickest  ***
!&E
!&E ** Purpose : Estimate of meridional fluxes of temperature and salinity
!&E              and other substances (advection and diffusion)
!&E              Advection uses QUICKEST scheme.
!&E
!&E ** Description : No horizontal diffusion at lower depths ( < hminkxky)
!&E                 - case of cyclicity in y : correct for northward propagation,
!&E                    uncorrect for southward propagation (stencil not long enough)
!&E
!&E ** Called by :
!&E
!&E ** External calls :
!&E
!&E ** Used ij-arrays : hty,hey,hy,fyeau,sal,temp,c(cv_wat),hzey,dy_v
!&E                     fsaly,ftempy,fy
!&E
!&E ** Modified variables : fsaly,ftempy,fy
!&E
!&E ** Reference : Debreu : Caspasthomas.....
!&E
!&E ** History :
!&E       !  2010-12 (V. Garnier) Original code
!&E       !  2016-04  (B.Thouvenin) applied to all substances (dissolved and particulate, include sand)
!&E       !  2016-12  (B.Thouvenin) version sedim_MUSTANG : only mixsed (mudsand not operationnal)
!&E
!&E---------------------------------------------------------------------





























































!! * Modules used
   USE parameters
   USE comvars2d,   ONLY : jb,jh,hty,hey,hy,h0fond,ky,hminkxky,dy_v,halfdt,l_obc_cycl_y,dx_v

   USE comfluxdo,   ONLY : fsaly,fyeau
   USE cometemp,    ONLY : ftempy

   USE comsubstance,ONLY : nv_adv,nv_grav,fy

   USE comMUSTANG,    ONLY : corfluy


   USE toolmpi, ONLY : ex_j_rsh,ex_j_rlg

   IMPLICIT NONE

!! * Arguments
   REAL(KIND=rsh),DIMENSION(kmax,liminm1:limaxp2,ljminm1:ljmaxp2),INTENT(in) :: sal,temp

   REAL(KIND=rsh),DIMENSION(nb_var,kmax,liminm1:limaxp2,ljminm1:ljmaxp2),INTENT(in) :: c


!! * Local declarations
   INTEGER                   :: i,j,k
   REAL(KIND=rsh), PARAMETER :: dsmall = 1.0d-20
   REAL(KIND=rsh)            :: vv,da,db,dc,vvv,cfl,     &
                                kyb,yas,yat,ybs,ybt,ycs,yct,        &
                                deltat,deltas

   INTEGER                              :: iv
   REAL(KIND=rsh), DIMENSION(nv_adv)    :: ya,yb,yc,delta


!!----------------------------------------------------------------------
!! * Executable part

!$OMP DO schedule(runtime),private(i,j,k,kyb,  &
!$OMP& yas,yat,ybs,ybt,ycs,yct,deltat,deltas,  &

!$OMP& iv,ya,yb,yc,delta,                      &

!$OMP& da,db,dc,vv,vvv,cfl)

   DO j=ljmin,ljmax
     DO i=liminp2,limaxm1

       IF (j >= jb(i) .AND. j <= jh(i)-1) THEN
         DO k=1,kmax
           IF (hty(i,j) <= 0.0_rsh .OR. hy(i,j)==-valmanq-h0fond) THEN

             fsaly(k,i,j)=0.0_rlg
             ftempy(k,i,j)=0.0_rlg


             fy(nv_grav+1:nv_adv,k,i,j)=0.0_rsh

           ELSE
             kyb=ky
             IF (hty(i,j) < hminkxky) kyb=0.0_rsh ! no diffusion for small water depth
             vv=fyeau(k,i,j)

             vvv = vv/(halfdt*hey(i,j))

             cfl = vvv*halfdt/dy_v(i,j)
                           
             IF (vv <= 0.0_rsh) THEN  ! southward advection
               da=(1.0_rsh/6.0_rsh)*(-1.0_rsh+cfl**2)
               db=(1.0_rsh/6.0_rsh)*(5.0_rsh-3.0_rsh*cfl-2.0_rsh*cfl**2)
               dc=(1.0_rsh/6.0_rsh)*(2.0_rsh+3.0_rsh*cfl+cfl**2)

               ybs=sal(k,i,j+1)
               ycs=sal(k,i,j)
               ybt=temp(k,i,j+1)
               yct=temp(k,i,j)


               yb(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j+1)
               yc(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j)


               IF (hty(i,j+1) > 0.0_rsh .AND. (j+1 < jh(i) .OR. l_obc_cycl_y)) THEN

                 yas=sal(k,i,j+2)
                 yat=temp(k,i,j+2)


                 ya(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j+2)

               ELSE

                 yas=ybs
                 yat=ybt


                 ya(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)

               END IF


               deltas=ybs-ycs
               deltat=ybt-yct


               delta(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)-yc(nv_grav+1:nv_adv)


             ELSE      ! northward advection

               da=(1.0_rsh/6.0_rsh)*(-1.0_rsh+cfl**2)
               db=(1.0_rsh/6.0_rsh)*(5.0_rsh+3.0_rsh*cfl-2.0_rsh*cfl**2)
               dc=(1.0_rsh/6.0_rsh)*(2.0_rsh-3.0_rsh*cfl+cfl**2)

               ybs=sal(k,i,j)
               ycs=sal(k,i,j+1)
               ybt=temp(k,i,j)
               yct=temp(k,i,j+1)


               yb(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j)
               yc(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j+1)

               IF (hty(i,j-1) > 0.0_rsh .AND. (j > jb(i) .OR. l_obc_cycl_y)) THEN

                 yas=sal(k,i,j-1)
                 yat=temp(k,i,j-1)


                 ya(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j-1)

               ELSE

                 yas=ybs
                 yat=ybt


                 ya(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)

               END IF

               deltas=ycs-ybs
               deltat=yct-ybt


               delta(nv_grav+1:nv_adv)=yc(nv_grav+1:nv_adv)-yb(nv_grav+1:nv_adv)


             END IF       ! ends test on velocity sign




! flux of salinity advection
! --------------------------

             fsaly(k,i,j) = vv*(da*yas+db*ybs+dc*ycs)

! flux of temperature advection
! -----------------------------

             ftempy(k,i,j) = vv*(da*yat+db*ybt+dc*yct)

! key_offline




! advection flux of other substances
! ----------------------------------

             DO iv=nv_grav+1,nv_adv
               fy(iv,k,i,j) = vv*(da*ya(iv)+db*yb(iv)+dc*yc(iv))
             END DO




! Advection/diffusion term (iso-sigma)
! ------------------------------------

             ftempy(k,i,j)=ftempy(k,i,j)-hey(i,j)*kyb*deltat/dy_v(i,j)*halfdt
             fsaly(k,i,j)=fsaly(k,i,j)-hey(i,j)*kyb*deltas/dy_v(i,j)*halfdt              





             DO iv=nv_grav+1,nv_adv

! Advection/diffusion term (iso-sigma)
! ------------------------------------

               fy(iv,k,i,j) = fy(iv,k,i,j) - hey(i,j)*kyb*delta(iv)/dy_v(i,j)*halfdt



               IF (k.eq.1) fy(iv,k,i,j)=fy(iv,k,i,j)*corfluy(iv,i,j)

             END DO


           END IF ! ends test on water depth
         END DO ! ends loop on k
       END IF ! for selecting right j loop
     END DO ! ends loop on i
   END DO ! ends loop on j
!$OMP END DO

!$OMP barrier
!$OMP master

   CALL ex_j_rlg(-1,0,kmax,limin,limax,ljminm1,ljmax,fsaly(:,limin:limax,ljminm1:ljmax))
   CALL ex_j_rlg(-1,0,kmax,limin,limax,ljminm1,ljmax,ftempy(:,limin:limax,ljminm1:ljmax))


   CALL ex_j_rsh(-1,0,nv_adv*kmax,limin,limax,ljminm1,ljmax,fy(:,:,limin:limax,ljminm1:ljmax))

!$OMP end master
!$OMP barrier

!$OMP flush(fsaly,ftempy)


!$OMP flush(fy)


  END SUBROUTINE tssub_advdify_q
