  SUBROUTINE tssub_advdifx_q(sal,temp   &
#ifdef key_substance
                                      ,c &
#endif
                                        )

   !&E---------------------------------------------------------------------
   !&E                 ***  ROUTINE tssub_advdifx_quickest  ***
   !&E
   !&E ** Purpose : Estimate of zonal fluxes of temperature and salinity
   !&E              and other substances (advection and diffusion)
   !&E              Advection uses QUICKEST scheme.
   !&E
   !&E ** Description : No horizontal diffusion at lower depths ( < hminkxky)
   !&E                  - case of cyclicity in y : correct for eastward propagation,
   !&E                    uncorrect for westward propagation (stencil not long enough)
   !&E
   !&E ** Called by :
   !&E
   !&E ** External calls :
   !&E
   !&E ** Used ij-arrays : htx,hex,hx,fxeau,sal,temp,c(cv_wat),hzex,dx_u 
   !&E                     fsalx,ftempx,fx 
   !&E  
   !&E ** Modified variables : fsalx,ftempx,fx
   !&E
   !&E ** Reference : Debreu : Caspasthomas.....
   !&E
   !&E ** History :
   !&E       !  2010-12 (V. Garnier) Original code
   !&E       !  2016-04 (B.Thouvenin) applied to all substances (dissolved and particulate)
   !&E       !  2016-12  (B.Thouvenin) version sedim_MUSTANG : only mixsed (mudsand not operationnal)
   !&E
   !&E---------------------------------------------------------------------

#include "toolcpp.h"

   !! * Modules used
   USE parameters
   USE comvars2d, ONLY : ig,id,htx,hex,hx,kx,h0fond,hminkxky,dx_u,halfdt,l_obc_cycl_x,dy_u
#if defined key_siggen || defined key_gencoord
   USE comsiggen, ONLY : hzex
#endif
   USE comfluxdo, ONLY : fsalx,fxeau
   USE cometemp,  ONLY : ftempx
#ifdef key_substance
   USE comsubstance, ONLY : nv_adv,nv_grav,fx
#ifdef key_sedim_MUSTANG
   USE comMUSTANG,    ONLY : corflux
#endif
#endif
   USE_MPI toolmpi, ONLY : ex_i_rsh,ex_i_rlg

   IMPLICIT NONE

   !! * Arguments
   REAL(KIND=rsh),DIMENSION(kmax,liminm1:limaxp2,ljminm1:ljmaxp2),INTENT(in) :: sal,temp
#ifdef key_substance
   REAL(KIND=rsh),DIMENSION(nb_var,kmax,liminm1:limaxp2,ljminm1:ljmaxp2),INTENT(in) :: c
#endif

   !! * Local declarations
   INTEGER                   :: i,j,k
   REAL(KIND=rsh), PARAMETER :: dsmall = 1.0d-20
   REAL(KIND=rsh)            :: uu,da,db,dc,uuu,cfl,     &
                                kxb,yas,yat,ybs,ybt,ycs,yct,        &
                                deltat,deltas
#ifdef key_substance
   INTEGER                              :: iv
   REAL(KIND=rsh), DIMENSION(nv_adv)    :: ya,yb,yc,delta
#endif

   !!----------------------------------------------------------------------
   !! * Executable part

!$OMP DO schedule(runtime),private(i,j,k,kxb,  &
!$OMP& yas,yat,ybs,ybt,ycs,yct,deltat,deltas,  &
#ifdef key_substance
!$OMP& iv,ya,yb,yc,delta,                      &
#endif
!$OMP& da,db,dc,uu,uuu,cfl)

   DO j=ljminp2,ljmaxm1
     DO i=MAX0(limin,ig(j)),MIN0(limax,id(j)-1)
       DO k=1,kmax
         IF (htx(i,j) <= 0.0_rsh .OR. hx(i,j) == -valmanq-h0fond) THEN
#if ! defined key_offline
           fsalx(k,i,j)=0.0_rlg
           ftempx(k,i,j)=0.0_rlg
#endif
#ifdef key_substance
           !refonte subtances advection avril 2016
           fx(nv_grav+1:nv_adv,k,i,j)=0.0_rsh
#endif
         ELSE
           kxb=kx
           IF (htx(i,j) < hminkxky) kxb=0.0_rsh ! no diffusion for small water depth
           uu=fxeau(k,i,j)
#if defined key_siggen || defined key_gencoord
           uuu = uu/(halfdt*hzex(k,i,j))
#else
           uuu = uu/(halfdt*hex(i,j))
#endif
           cfl = uuu*halfdt/dx_u(i,j)

           IF (uu <= 0.0_rsh) THEN  ! westward advection
             da=(1.0_rsh/6.0_rsh)*(-1.0_rsh+cfl**2)
             db=(1.0_rsh/6.0_rsh)*(5.0_rsh-3.0_rsh*cfl-2.0_rsh*cfl**2)
             dc=(1.0_rsh/6.0_rsh)*(2.0_rsh+3.0_rsh*cfl+cfl**2)
#if ! defined key_offline
             ybs=sal(k,i+1,j)
             ycs=sal(k,i,j)
             ybt=temp(k,i+1,j)
             yct=temp(k,i,j)
#endif
#ifdef key_substance
             yb(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i+1,j)
             yc(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j)
#endif
             IF (htx(i+1,j) > 0.0_rsh .AND. (i+1 < id(j) .OR. l_obc_cycl_x)) THEN
#if ! defined key_offline
               yas=sal(k,i+2,j)
               yat=temp(k,i+2,j)
#endif
#ifdef key_substance
               ya(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i+2,j)
#endif
             ELSE
#if ! defined key_offline
               yas=ybs
               yat=ybt
#endif
#ifdef key_substance
               ya(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)
#endif
             END IF
#if ! defined key_offline
             deltas=ybs-ycs
             deltat=ybt-yct
#endif
#ifdef key_substance
             delta(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)-yc(nv_grav+1:nv_adv)
#endif

           ELSE  ! eastward advection

             da=(1.0_rsh/6.0_rsh)*(-1.0_rsh+cfl**2)
             db=(1.0_rsh/6.0_rsh)*(5.0_rsh+3.0_rsh*cfl-2.0_rsh*cfl**2)
             dc=(1.0_rsh/6.0_rsh)*(2.0_rsh-3.0_rsh*cfl+cfl**2)
#if ! defined key_offline
             ybs=sal(k,i,j)
             ycs=sal(k,i+1,j)
             ybt=temp(k,i,j)
             yct=temp(k,i+1,j)
#endif
#ifdef key_substance
             yb(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i,j)
             yc(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i+1,j)
#endif
             IF (htx(i-1,j) > 0.0_rsh .AND. (i > ig(j) .OR. l_obc_cycl_x)) THEN
!              IF (hex(i-1,j) > 0.0_rsh) THEN
#if ! defined key_offline
               yas=sal(k,i-1,j)
               yat=temp(k,i-1,j)
#endif
#ifdef key_substance
               ya(nv_grav+1:nv_adv)=c(nv_grav+1:nv_adv,k,i-1,j)
#endif
             ELSE
#if ! defined key_offline
               yas=ybs
               yat=ybt
#endif
#ifdef key_substance
               ya(nv_grav+1:nv_adv)=yb(nv_grav+1:nv_adv)
#endif
             END IF
#if ! defined key_offline
             deltas=ycs-ybs
             deltat=yct-ybt
#endif
#ifdef key_substance
             delta(nv_grav+1:nv_adv)=yc(nv_grav+1:nv_adv)-yb(nv_grav+1:nv_adv)
#endif

           END IF    ! ends test on velocity sign


#if ! defined key_offline

   ! advection flux of salinity
   ! --------------------------

           fsalx(k,i,j)  = uu*(da*yas+db*ybs+dc*ycs)

   ! flux of temperature advection
   ! -----------------------------

           ftempx(k,i,j)  = uu*(da*yat+db*ybt+dc*yct)

   ! key_offline
#endif

#ifdef key_substance

   ! advection flux of other substances
   ! ----------------------------------

           DO iv=nv_grav+1,nv_adv
             fx(iv,k,i,j) = uu*(da*ya(iv)+db*yb(iv)+dc*yc(iv))
           END DO
#endif

#if ! defined key_offline
#if defined key_ts_diffh_geo || defined key_ts_diffh_rho
   ! Advection term (iso-sigma) alone
   ! --------------------------------
           ftempx(k,i,j) = ftempx(k,i,j)*dy_u(i,j)
           fsalx(k,i,j)  = fsalx(k,i,j)*dy_u(i,j)
#else
   ! Advection/diffusion term (iso-sigma)
   ! ----------------------------------
#if defined key_siggen || defined key_gencoord
           ftempx(k,i,j) = ftempx(k,i,j)-hzex(k,i,j)*kxb*deltat/dx_u(i,j)*halfdt
           fsalx(k,i,j) = fsalx(k,i,j)-hzex(k,i,j)*kxb*deltas/dx_u(i,j)*halfdt            
#else
           ftempx(k,i,j) = ftempx(k,i,j)-hex(i,j)*kxb*deltat/dx_u(i,j)*halfdt
           fsalx(k,i,j) = fsalx(k,i,j)-hex(i,j)*kxb*deltas/dx_u(i,j)*halfdt            
#endif
#endif
#endif

#ifdef key_substance
           DO iv=nv_grav+1,nv_adv
#if defined key_ts_diffh_geo || defined key_ts_diffh_rho
   ! Advection term (iso-sigma) alone
   ! --------------------------------
             fx(iv,k,i,j) = fx(iv,k,i,j)*dy_u(i,j)
#else
   ! Advection/diffusion term (iso-sigma)
   ! ----------------------------------
#if defined key_siggen || defined key_gencoord
             fx(iv,k,i,j) = fx(iv,k,i,j) - hzex(k,i,j)*kxb*delta(iv)/dx_u(i,j)*halfdt
#else
             fx(iv,k,i,j) = fx(iv,k,i,j) - hex(i,j)*kxb*delta(iv)/dx_u(i,j)*halfdt
#endif
#endif
#ifdef key_sedim_MUSTANG
             IF (k == 1) fx(iv,k,i,j)=fx(iv,k,i,j)*corflux(iv,i,j)
#endif
           END DO
#endif

         END IF ! ends test on water depth
       END DO ! ends loop on k
     END DO ! ends loop on i
   END DO ! ends loop on j
!$OMP END DO

OMPMPI barrier
OMPMPI master
#if ! defined key_offline
   CALL_MPI ex_i_rlg(-1,0,kmax,liminm1,limax,ljmin,ljmax,fsalx(:,liminm1:limax,ljmin:ljmax))
   CALL_MPI ex_i_rlg(-1,0,kmax,liminm1,limax,ljmin,ljmax,ftempx(:,liminm1:limax,ljmin:ljmax))
#endif
#ifdef key_substance
   CALL_MPI ex_i_rsh(-1,0,nv_adv*kmax,liminm1,limax,ljmin,ljmax,fx(:,:,liminm1:limax,ljmin:ljmax))
#endif
OMPMPI end master
OMPMPI barrier
#if ! defined key_offline
OMPMPI flush(fsalx,ftempx)
#endif
#ifdef key_substance
OMPMPI flush(fx)
#endif

  END SUBROUTINE tssub_advdifx_q
